
**Programmering C. Øvelse med flere WinForms ting.** jan. 2013. prso.

Du kender allerede de mest almindelige kontroller, såsom TextBox, Label, Button. I denne øvelse skal du afprøve nogle flere ting, som du kan bruge, når du skal lave et "rigtigt" program, f.eks. i et eksamensprojekt, og ikke bare et øvelsesprogram.

1. Jeg vil **åbne et nyt vindue**. Når brugeren klikker på en knap på min Form1 skal der åbnes en ny Form2.

* Opret et nyt Projekt med en Form1.
* Under menuen "Project" vælg "Add Windows Form..." for at tilføje endnu en Form. Den får navnet Form2.
* Placer en knap på din Form1. På denne knap udføres blot koden Form2.Show()
* Prøv engang. Bemærk, at Form2 kan komme bagved Form1. Det kan du undgå ved i stedet at skrive Form2.ShowDialog(). Prøv det.
* Nu kan Form2 ikke komme bagved Form1, men dit program kan stadig komme bagved andre programmer. Hvis du vil undgå det, skal du sætte egenskaben TopMost = True på dine Forms. Prøv det.

1. Vil du ikke have, at brugeren skal kunne minimere eller maksimere dit programs vindue? Så sæt egenskaberne Form1.MinimizeBox og Form1.MaximizeBox til False. Prøv det.
2. Du vil fra en knap på Form1 **lukke** Form2 igen? Så bruger du bare kommandoen Form2.Close(). Prøv det. Hvis det derimod skal ske fra en knap på Form2 skal man skrive Me.Close()
3. Man kan få vinduer til at være **halvgennemsigtige**. Det gør man ved at sætte Opacity-egenskaben til et tal mindre end 100%. I dette eksempel er Form2.Opacity = 50%:



1. Vil du på Form1 kunne åbne Form2 med både knappen, du allerede har, og **med en funktionstast**? Så prøv at tilføje flg. kode til Form1:

Private Sub Form1\_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs)

Handles Me.KeyDown

If (e.KeyCode = Keys.F9) Then

'Brugeren trykkede på F9 tasten. Åbn Form2.

'Husk at sætte Form1.KeyPreview = True

Form2.ShowDialog()

End If


End Sub

1. Hvordan sætter jeg en **ikon** på mit programvindue?

Find en .ico fil på din computer (søg fil \*.ico i stifinderen) eller find én på nettet, du kan downloade. Den skal tilknyttes under Form1.Icon. Prøv det.

Vil du tegne din egen ikon, eller modificere en eksisterende? Så skal du bruge en ikon editor, find én f.eks. på <http://www.freedownloadscenter.com> eller <http://www.tucows.com/> eller lignende steder.

1. Går dit program død uden at opdatere skærmen, mens det kører i løkke? Så skal du tilføje en Me.Refresh() efter hvert gennemløb. Prøv f.eks. at lave en knap, som starter en løkke, som tager nogen tid at gennemløbe. F.eks.:



Private Sub ButtonCount\_Click(ByVal sender As System.Object, ByVal e As \_ System.EventArgs) Handles ButtonCount.Click

For i As Integer = 1 To 10000

'Tæl op på tallet i TextBoxCount

TextBoxCount.Text = TextBoxCount.Text + 1

Next

End Sub

Du ser, at TextBoxCount først opdateres når løkken er færdig. Hvor lang tid tager løkken?

Prøv nu at tilføje kommandoen Me.Refresh() for hvert løkkegennemløb, altså:

For i As Integer = 1 To 10000

'Tæl op på tallet i TextBoxCount

TextBoxCount.Text = TextBoxCount.Text + 1

Me.Refresh()

Next i

Hvordan opdateres TextBoxCount nu? Hvor lang tid tager løkken nu?

1. Kunne det ikke være brugervenligt at vise **vente-musemarkør** mens dit program har travlt? Prøv denne kode:

Private Sub ButtonCount\_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles \_ ButtonCount.Click

'Sæt timeglas cursor mens løkken kører

Me.Cursor = System.Windows.Forms.Cursors.WaitCursor

For i As Integer = 1 To 1000

'Tæl op på tallet i TextBoxCount

TextBoxCount.Text = TextBoxCount.Text + 1

Me.Refresh()

Next i

'Sæt normal cursor igen efter løkken er færdig

Me.Cursor() = System.Windows.Forms.Cursors.Default

End Sub

Der findes andre cursors end WaitCursor, se selv.

1. En **pause** eller ventetid kan indlægges med Sleep(), f.eks.: System.Threading.Thread.Sleep(5000)

5000 betyder 5000 millisekunder = 5 sekunder. Bemærk, at computeren ikke er ”låst” imens.


1. **Afspilning af lydfil.**

En lydfil kan afspilles med f.eks. My.Computer.Audio.Play("C:\Temp\Chimes.wav", AudioPlayMode.Background)

AudioPlayMode.Background betyder, at programmet fortsætter mens lydfilen afspilles. Chimes.wav er en tilfældig lydfil, som jeg har liggende på min harddisk i mappen C:\Temp.

Hvis jeg kører mit program på en anden computer, skal jeg huske at kopiere lydfilen med over. Det er ikke smart. Det er bedre at have lydfilen INDE I mit program. Det gør jeg ved at lægge lydfilen i mit programs RESOURCER:


Højreklik på ”My Project” i ”Solution Explorer” og vælg fanen ”Resources” og ”Add Ressource” og ”Existing file” og vælg filen, som du vil tilføje:



Jeg kan nu bare skrive: My.Computer.Audio.Play(My.Resources.chimes, AudioPlayMode.Background)

1. Nu vi snakker om brugervenlighed: prøv at sætte en **ToolTip** på en knap:

Tilføj fra værktøjskassen en "ToolTip" til din Form1 - den skal bare beholde navnet ToolTip1. Den kommer til at ligge nedenunder din Form1:



Tilføj nu en Form1\_Load() hvis du ikke allerede har den. Det gør du bare ved at dobbeltklikke et sted på din Form1. I denne Form1\_Load() tilføjer du så kommandoen SetToolTip som vist herunder:

Private Sub Form1\_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles \_ MyBase.Load

'Tilføj en ToolTip tekst til Tæl-knappen

Call ToolTip1.SetToolTip(ButtonCount, "Klik her når du vil starte løkken")

End Sub

Afprøv: Start dit program og hold musemarkøren hen over knappen. Så skulle der gerne blive vist en ToolTip sådan her:

1. Hvordan får jeg genereret **et tilfældigt tal**? Sådan her (jeg opretter en knap med navnet ButtonShowRandom):

Dim RandomObj As New Random

Private Sub ButtonShowRandom\_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles \_ ButtonShowRandom.Click

'Find og vis et tilfældigt heltal i intervallet mellem 1 og 10

'(1 er med, 10 er ikke med)

MsgBox(RandomObj.Next(1, 10), Title:="Tilfældigt tal")

End Sub

1. Når brugeren **lukker** mit program, vil jeg gerne spørge hende, om hun nu virkelig også mener det. Prøv at indsæt flg. kode i din Form1:

Private Sub Form1\_FormClosing(ByVal sender As Object, ByVal e As \_ System.Windows.Forms.FormClosingEventArgs) Handles Me.FormClosing

If (MessageBox.Show("Vil du virkelig lukke programmet?", \_

"MitProgram", \_

MessageBoxButtons.YesNo, \_

MessageBoxIcon.Question, \_

MessageBoxDefaultButton.Button1, \_

0) = Windows.Forms.DialogResult.No) Then

'Bruger siger nej, luk ikke alligevel


e.Cancel = True 'forhindre luk

End If

End Sub

Kan du se hvad hver parameter betyder?

1. Det kan være rart at kunne indtaste noget og så afslutte med at taste **”Enter”** i stedet for at skulle klikke på en knap. Det kan man gøre således:



Public Class Form1

Private Sub TextBox1\_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles TextBox1.KeyDown

If e.KeyCode = Keys.Enter Then

'Bruger taster 'Enter' => vis summen af tallene

Call VisSum()

End If

End Sub

Private Sub TextBox2\_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles TextBox2.KeyDown

If e.KeyCode = Keys.Enter Then

'Bruger taster 'Enter' => vis summen af tallene

Call VisSum()

End If

End Sub

Private Sub VisSum()

'Vis summen af de to talfelter

MsgBox("Summen er: " & Val(TextBox1.Text) + Val(TextBox2.Text))

End Sub

End Class

1. Vil du fra dit program **åbne en website** i din standardbrowser: Process.Start("www.eucsj.dk")
2. Vil du fra dit program **starte et andet program**: Process.Start("C:\Temp\AndetProgram.exe")
3. **Programmatisk oprettelse af objekter.** Sådan opretter man en **matrix af Pictureboxe**, f.eks. en spilleplade:

Public Class Form1

'Spillepladen har 9 felter vandret og 3 felter lodret

Const ANTAL\_FELTER\_X As Integer = 9

Const ANTAL\_FELTER\_Y As Integer = 3

'Erklær Pictureboxene – 2-dimensionelt array

Dim PictureBoxFelt(ANTAL\_FELTER\_X, ANTAL\_FELTER\_Y) As PictureBox

Private Sub Form1\_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

'Ved program start: Opret alle picturebox felter på spillepladen

For x As Integer = 1 To ANTAL\_FELTER\_X

For y As Integer = 1 To ANTAL\_FELTER\_Y

'Opret nyt object

PictureBoxFelt(x, y) = New PictureBox

'Sæt egenskaber størrelse, position, farve, osv.

PictureBoxFelt(x, y).Size = New System.Drawing.Size(50, 50)

'Placering afhænger af x og y:

PictureBoxFelt(x, y).Location = New System.Drawing.Point(10 + x \* 60, 10 + y \* 60)

PictureBoxFelt(x, y).BackColor = Color.Aqua

PictureBoxFelt(x, y).SizeMode = PictureBoxSizeMode.StretchImage

'Tilknyt pictureboxen til Form1

Me.Controls.Add(Me.PictureBoxFelt(x, y))

'Sæt klik-rutine til sub'en KlikFelt().

'Dvs. KlikFelt() bliver FÆLLES klik-rutine for ALLE pictureboxene

AddHandler PictureBoxFelt(x, y).Click, AddressOf KlikFelt

Next y

Next x

End Sub

'Klik-rutine fælles for alle pictureboxes på spillepladen

Private Sub KlikFelt(ByVal sender As System.Object, ByVal e As System.EventArgs)

'Find den picturebox, der blev klikket på

Dim PictureBoxKlikketPå As PictureBox = sender

For x As Integer = 1 To ANTAL\_FELTER\_X

For y As Integer = 1 To ANTAL\_FELTER\_Y

If PictureBoxFelt(x, y) Is sender Then

'Fundet. Den picturebox, der blev klikket på, er PictureBoxFelt(x, y)

MsgBox("Der blev klikket på: x=" & x & ", y=" & y)

'sæt Dronning-billede på den picturebox, der blev klikket på

PictureBoxFelt(x, y).Image = My.Resources.ResourceManager.GetObject("Dronning")

'Ingen grund til at lede videre; der kan kun klikkes på én picturebox

Exit Sub

End If

Next y


Next x

End Sub

End Class

1. Sådan laver man **drag-and-drop** af en enkelt PictureBox. Vi bygger videre på den foregående øvelse. I eksemplet vil vi trække en PictureBox med navnet PictureBoxToDrag hen over spillepladefelterne. Hvis man smider den over et tilladt felt, vil feltet skifte billede:





Øverst i koden skal der erklæres nogle variable:

'Variable til brug for drag-n-drop:

Private Dragging As Boolean = False

Private PictureBoxWhileDragging As PictureBox = Nothing

Dim StartMousePos As Point

Her er de procedurer og funktioner, som håndterer drag-n-drop:

'Find ud af om objektet MÅ droppes over dette felt x,y

Private Function CanDrop(ByVal x As Integer, ByVal y As Integer) As Boolean

'Dette skal nok justeres i hvert enkelt program

If (PictureBoxWhileDragging.Left >= PictureBoxFelt(x, y).Left And \_

PictureBoxWhileDragging.Left <= PictureBoxFelt(x, y).Right) AndAlso \_

(PictureBoxWhileDragging.Top >= PictureBoxFelt(x, y).Top And \_

PictureBoxWhileDragging.Top <= PictureBoxFelt(x, y).Bottom) Then

'PictureBoxWhileDragging befinder sig over et tilladt felt: drop er tilladt

Return True

Else

'Drop er ikke tilladt

Return False

End If

End Function

'Venstre museknap aktiveres på den PictureBox, som skal trækkes

'Bemærk: så længe museknappen er nede, er PictureBoxToDrag er det aktive objekt,

'dvs. PictureBoxToDrag modtager f.eks. .MouseMove og .MouseUp -events

Private Sub PictureBoxToDrag\_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBoxToDrag.MouseDown

'Sæt flag: Drag-n-drop i gang

Dragging = True

'Opret ny PictureBox til at vise billede MENS der bliver trukket

PictureBoxWhileDragging = New PictureBox

PictureBoxWhileDragging.Size = PictureBoxToDrag.Size

PictureBoxWhileDragging.Image = PictureBoxToDrag.Image

PictureBoxWhileDragging.SizeMode = PictureBoxToDrag.SizeMode

'Husk positionen af musemarkøren på det tidspunkt hvor museknappen blev aktiveret

StartMousePos = PictureBoxToDrag.Location - e.Location

Me.Controls.Add(PictureBoxWhileDragging)

End Sub

'Musemarkøren flyttes mens PictureBoxToDrag er det aktive objekt

Private Sub PictureBoxToDrag\_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBoxToDrag.MouseMove

If Dragging Then

'PictureBoxToDrag er ved at blive trukket. Flyt billedet med musemarkøren

PictureBoxWhileDragging.Location = StartMousePos + e.Location

PictureBoxWhileDragging.BringToFront()

End If

End Sub

'Museknap slippes: drop

Private Sub PictureBoxToDrag\_MouseUp(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs) Handles PictureBoxToDrag.MouseUp

If Dragging Then

'PictureBoxToDrag er ved at blive trukket

Dragging = False

'Se om vi er over et tilladt felt

For x As Integer = 1 To ANTAL\_FELTER\_X

For y As Integer = 1 To ANTAL\_FELTER\_Y

If CanDrop(x, y) Then

'Drop over PictureBoxFelt(x, y) er tilladt. Sæt billede her.

PictureBoxFelt(x, y).Image = PictureBoxToDrag.Image

End If

Next y

Next x

End If

'Fjern midlertidigt billede



PictureBoxWhileDragging.SendToBack()

PictureBoxWhileDragging.Image = Nothing

PictureBoxWhileDragging = Nothing

End Sub

1. Sådan laver man **drag-and-drop** når de PictureBoxe, som skal trækkes, er oprettet programmatisk og er i et Array. Programmet herunder er selvstændigt, det bygger ikke på de foregående øvelser. I eksemplet vil vi trække en af de farvede PictureBoxe nederst hen på et af spillefelterne. Hvis man smider den over et tilladt felt, vil feltet skifte billede (her bruger vi baggrundsfarven i stedet for billedet):



Public Class Form1

'Spillepladens størrelse vandret=x og lodret=y

Const ANTAL\_FELTER\_X As Integer = 4

Const ANTAL\_FELTER\_Y As Integer = 3

Const ANTAL\_FELTER\_FARVE As Integer = 3

'Variable til brug for drag-n-drop:

Private Dragging As Boolean = False

Private PictureBoxWhileDragging As PictureBox = Nothing

Private ObjectToDrag As PictureBox = Nothing

Dim StartMousePos As Point

'Erklær Pictureboxene – 2-dimensionelt array

Dim PictureBoxFelt(ANTAL\_FELTER\_X, ANTAL\_FELTER\_Y) As PictureBox

Dim PictureBoxFarve(ANTAL\_FELTER\_FARVE) As PictureBox

Private Sub Form1\_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

Me.Width = 310

Me.Height = 400

Me.Text = "Drag-n-drop demo"

'Opret alle felter fra starten

OpretSpilleFelter()

OpretFarveFelter()

End Sub

Private Sub OpretSpilleFelter()

'Opret alle spillefelter på spillepladen

For x As Integer = 1 To ANTAL\_FELTER\_X

For y As Integer = 1 To ANTAL\_FELTER\_Y

'Opret nyt object

PictureBoxFelt(x, y) = New PictureBox

'Sæt egenskaber størrelse, position, farve, osv.

PictureBoxFelt(x, y).Size = New System.Drawing.Size(50, 50)

'Placering afhænger af x og y:

PictureBoxFelt(x, y).Location = New System.Drawing.Point(x \* 60 - 30, y \* 60 - 30)

PictureBoxFelt(x, y).BackColor = Color.Aqua

PictureBoxFelt(x, y).SizeMode = PictureBoxSizeMode.StretchImage

'Tilknyt pictureboxen til Form1

Me.Controls.Add(Me.PictureBoxFelt(x, y))

Next y

Next x

End Sub

Private Sub OpretFarveFelter()

'Opret de farve-felter på spillepladen, som skal kunne trækkes hen på et spillefelt

For x As Integer = 1 To ANTAL\_FELTER\_FARVE

'Opret nyt object

PictureBoxFarve(x) = New PictureBox

'Sæt egenskaber størrelse, position, farve, osv.

PictureBoxFarve(x).Size = New System.Drawing.Size(30, 30)

PictureBoxFarve(x).SizeMode = PictureBoxSizeMode.StretchImage

'Placering afhænger af x og y:

PictureBoxFarve(x).Location = New System.Drawing.Point(10 + x \* 60, 300)

'Tilknyt pictureboxen til Form1

Me.Controls.Add(Me.PictureBoxFarve(x))

'Sæt samme handlers for alle PictureBoxFarve

AddHandler PictureBoxFarve(x).MouseDown, AddressOf PictureBoxFarveToDrag\_MouseDown

AddHandler PictureBoxFarve(x).MouseMove, AddressOf PictureBoxFarveToDrag\_MouseMove

AddHandler PictureBoxFarve(x).MouseUp, AddressOf PictureBoxFarveToDrag\_MouseUp

Next x

'Her skulle vi så sætte .image på hver PictureBoxFarve

'Men i dette eksempel sætter vi kun baggrundsfarven

PictureBoxFarve(1).BackColor = Color.Red

PictureBoxFarve(2).BackColor = Color.Green

PictureBoxFarve(3).BackColor = Color.Yellow

End Sub

'Find ud af om PictureBoxWhileDragging MÅ droppes over feltet ObjectToGetDrop

Private Function CanDrop(ByVal ObjectToGetDrop As Object) As Boolean

If (PictureBoxWhileDragging.Left >= ObjectToGetDrop.Left And \_

PictureBoxWhileDragging.Left <= ObjectToGetDrop.Right) AndAlso \_

(PictureBoxWhileDragging.Top >= ObjectToGetDrop.Top And \_

PictureBoxWhileDragging.Top <= ObjectToGetDrop.Bottom) Then

'PictureBoxWhileDragging befinder sig (delvist) over et tilladt felt: drop er tilladt

Return True

Else

'Drop er ikke tilladt

Return False

End If

End Function

'Venstre museknap aktiveres på den PictureBox, som skal trækkes

Private Sub PictureBoxFarveToDrag\_MouseDown(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs)

'Sæt flag: Drag-n-drop i gang

Dragging = True

'Opret ny PictureBox til at vise billede MENS der bliver trukket

PictureBoxWhileDragging = New PictureBox

PictureBoxWhileDragging.Size = sender.Size

PictureBoxWhileDragging.Image = sender.Image

PictureBoxWhileDragging.SizeMode = sender.SizeMode

PictureBoxWhileDragging.BackColor = sender.BackColor

'Husk hvilket objekt, der bliver trukket

ObjectToDrag = sender

'Husk positionen af musemarkøren på det tidspunkt hvor museknappen blev aktiveret

StartMousePos = sender.Location - e.Location

Me.Controls.Add(PictureBoxWhileDragging)

End Sub

'Musemarkøren flyttes mens PictureBoxFarveToDrag er det aktive objekt

Private Sub PictureBoxFarveToDrag\_MouseMove(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs)

If Dragging Then

'Drag-n-drop i gang

'Flyt PictureBoxWhileDragging sammen med musemarkøren

PictureBoxWhileDragging.Location = StartMousePos + e.Location

PictureBoxWhileDragging.BringToFront()

End If

End Sub

'Museknap slippes: drop

Private Sub PictureBoxFarveToDrag\_MouseUp(ByVal sender As Object, ByVal e As System.Windows.Forms.MouseEventArgs)

If Not Dragging Then

'Vi er slet ikke i gang med drag-n-drop: gør ingenting

Exit Sub

End If

'PictureBoxToDrag er ved at blive trukket

'Når musetasten slippes stopper drag-n-drop, uanset om vi må droppe eller ej

Dragging = False

'Se om vi er over et felt hvor drop er tilladt

For x As Integer = 1 To ANTAL\_FELTER\_X

For y As Integer = 1 To ANTAL\_FELTER\_Y

If CanDrop(PictureBoxFelt(x, y)) Then

'Drop af PictureBoxWhileDragging over PictureBoxFelt(x, y) er tilladt:

'Sæt billede her.

PictureBoxFelt(x, y).Image = PictureBoxWhileDragging.Image

'Sæt også baggrundsfarve, i det tilfælde at vi ikke har et image

PictureBoxFelt(x, y).BackColor = PictureBoxWhileDragging.BackColor

'-->> HVIS objektet skal kunne FLYTTES VIDERE flere gange, så skal

'-->> nedenstående to linjer indsættes I STEDET FOR de to linjer herover

'-->> og remove() herunder skal også fjernes

'ObjectToDrag.Location = PictureBoxFelt(x, y).Location

'ObjectToDrag.BringToFront()

'Fjern det oprindelige object

'-->> Denne linje skal fjernes, hvis drag-n-drop skal være KOPI

'-->> Linjen skal være med hvis det er en FLYTNING

'Me.Controls.Remove(ObjectToDrag)

End If

Next y

Next x

'Fjern midlertidigt billede

'dette skal gøres uanset om objektet bliver droppet eller ej

Me.Controls.Remove(PictureBoxWhileDragging)

PictureBoxWhileDragging = Nothing

End Sub

End Class

1. Sådan **sender man en email via sin gmail-konto**

Public Class Form1

Private Sub Form1\_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

Dim client As New System.Net.Mail.SmtpClient()

Dim sendTo As New System.Net.Mail.MailAddress("Modtager@gmail.com")

Dim from As System.Net.Mail.MailAddress = New System.Net.Mail.MailAddress("Afsender@gmail.com")

Dim message As New System.Net.Mail.MailMessage(from, sendTo)

message.IsBodyHtml = True

message.Subject = "HI"

message.Body = "Got it!!"

' Use the same account in app.config to authenticate.

Dim basicAuthenticationInfo As New System.Net.NetworkCredential("Afsender@gmail.com", "KontoKodeord")

client.Host = "smtp.gmail.com"

client.UseDefaultCredentials = False

client.Credentials = basicAuthenticationInfo

client.EnableSsl = True

client.Port = 587

Try

client.Send(message)

'Sendt uden fejl

MessageBox.Show("Email afsendt")

Catch ex As Exception

'Fejl

MessageBox.Show(ex.Message)

End Try

End Sub

End Class

1. Eksempel på at fylde en **combobox** med emner (Items), skrive disse emner i en tekstfil, læse tekstfilen igen og fylde hvert emne ind i comboboxen igen. På Form1 er eneste object en ComboBox med navnet ComboBox1.

Eksemplet er kun for at illustrere tingene, man ville ikke lægge disse ting i Form1\_Load().

Public Class Form1

Private Sub Form1\_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

Const FELTLÆNGDE = 50

Const FilNavn As String = "testfil.txt"

Dim Tilføj As Boolean

'Fyld nogle items ind i comboboxen

ComboBox1.Items.Add("Medina")

ComboBox1.Items.Add("Nephew")

ComboBox1.Items.Add("DJ Tholstrup")

'Gem disse items i en tekstfil. 50 tegn til hver.

For Each item In ComboBox1.Items

'Skriv Comboboxens Items i tekstfilen, hverrt Item skrives i et 50 tegn langt felt

My.Computer.FileSystem.WriteAllText(FilNavn, item.ToString.PadRight(FELTLÆNGDE), append:=Tilføj)

Tilføj = True 'Variablen Tilføj er False første gang, derefter True

Next item

'Læs filen tilbage og ind i comboboxen

Dim str As String 'Strengvariabel til filens indhold

Dim felt As Integer = 0 'tæller for felter, hvert felt er 50 tegn langt

Dim TekstFelt As String = "filen er tom" 'Strengvariabel til felterne, som læses i filen

'Læs filen

str = My.Computer.FileSystem.ReadAllText(FilNavn)

TekstFelt = Mid(str, 1, FELTLÆNGDE).Trim 'Første felt

Do Until TekstFelt = ""

'Tilføj teksten i combo boxen

ComboBox1.Items.Add(TekstFelt)

'næste felt. Trim fjerner blanktegnene efter teksten

felt = felt + 1 'Næste felt

TekstFelt = Mid(str, felt \* FELTLÆNGDE + 1, FELTLÆNGDE).Trim

Loop

End Sub

End Class

1. Indtastning af kommatal? Hvis du gør sådan her, så fungerer det med KOMMATEGN som decimaltegn:

Dim Tal As Single

If IsNumeric(TextBox1.Text) Then

Tal = TextBox1.Text 'man skal taste kommategn som decimaltegn

End If

1. Styring af ojekters position x-y: F.eks.:

Button1.Left = Button1.Left + 50 'Flytter knappen 50 pixels mod højre

Button1.Top = Button1.Top + 50 'Flytter knappen 50 pixels nedad

1. Afvis ugyldige indtastninger, i dette tilfælde er kun tal tilladt:

Private Sub TextBox1\_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles TextBox1.KeyDown

Dim Allowed = "0123456789" & vbBack 'Tilladte tegn

If Allowed.ToLower.IndexOf(e.KeyChar) = -1 Then

'Det indtastede tegn ikke blandt de tilladte

e.Handled = True

End If

End Sub

Alternativt kan man gøre sådan:

Private Sub TextBox1\_KeyDown(ByVal sender As Object, ByVal e As System.Windows.Forms.KeyEventArgs) Handles TextBox1.KeyDown

'Gør at der kun kan indtastes ”Digit” og ”Control character”

If Not Char.IsDigit(e.KeyChar) And Not Char.IsControl(e.KeyChar) Then


e.Handled = True

End If

End Sub

1. Håndtering af highscore liste (sorteret) + skrivning i fil.

Demo programmet kan vise en liste med high score, dvs. navn og pointtal. Når der indsættes nye (indtastning + OK) bliver de indsat det ”rigtige” sted i listen sådan at listen altid er sorteret med de højeste pointtal øverst.



Public Class Form1

'----------------------------------------------------------------------------------------------

'Program, som viser, hvordan man kan håndtere en highscoreliste, gemt i en fil. prso marts 2013.

'----------------------------------------------------------------------------------------------

'Opret array med størrelsen 1,

'vi udvider det efter behov

'Hver highscore registrering har navn og pointtal:

Dim HighScoreName(0) As String

Dim HighScoreCount(0) As Integer

Private Sub Form1\_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

'Ved programstart: læs fil med tidligere high scores

ReadHighScoreFile()

End Sub

'Læs fil med tidligere high scores

Private Sub ReadHighScoreFile()

Dim fileReader As System.IO.StreamReader

Dim FileLine As String

'åbn fil med navnet HighScore.txt. Placering: samme sted som projektets .exe fil

fileReader = My.Computer.FileSystem.OpenTextFileReader("HighScore.txt")

FileLine = fileReader.ReadLine()

While (FileLine <> "") 'loop så længe der er linjer i filen

'udvid array med én plads

ReDim Preserve HighScoreName(UBound(HighScoreName) + 1)

ReDim Preserve HighScoreCount(UBound(HighScoreCount) + 1)

'Highscore navn og pointtal læst fra filen indsættes i

'øverste (nyoprettede) plads i arrayet

'I hver linje står navnet på de første 20 pladser og scoren fra plads 22

'f.x.: "Spiller1 : 230"

HighScoreName(UBound(HighScoreName)) = Mid(FileLine, 1, 20)

HighScoreCount(UBound(HighScoreCount)) = Val(Mid(FileLine, 22, 5))

'læs næste linje fra filen

FileLine = fileReader.ReadLine()

End While

fileReader.Close()

End Sub

'Skriv fil med alle high scores. Overskriv evt. eksisterende fil.

Private Sub WriteHighScoreFile()

Dim fileWriter As System.IO.StreamWriter

Dim FileLine As String

'opret fil. Placering: samme sted som projektets .exe fil

'append:=False betyder overskriv, ikke tilføj

fileWriter = My.Computer.FileSystem.OpenTextFileWriter("HighScore.txt", append:=False)

For i As Integer = 1 To UBound(HighScoreCount)

'I hver linje står navnet på de første 20 pladser og scoren fra plads 22

'f.x.: "Spiller1 : 230"

If (HighScoreName(i) IsNot Nothing) AndAlso (HighScoreName(i).Trim <> "") Then

'hvis et navn er tomt skrives det ikke i filen. På denne måde kan highscores fjernes

FileLine = HighScoreName(i).PadRight(20) & ":" & HighScoreCount(i).ToString.PadLeft(5)

fileWriter.WriteLine(FileLine)

End If

Next i

fileWriter.Close()

End Sub

'Ny high score - bruger klikker OK: indsæt i array og gem i fil

Private Sub ButtonAccept\_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ButtonAccept.Click

'udvid med én plads

ReDim Preserve HighScoreName(UBound(HighScoreName) + 1)

ReDim Preserve HighScoreCount(UBound(HighScoreCount) + 1)

'indsæt den nye highscore på det rigtige sted sådan at højeste scores står øverst

For i As Integer = 1 To UBound(HighScoreCount)

If (Val(TextBoxScore.Text) > HighScoreCount(i)) Then

'den nye highscore er større end HighScoreCount(i): indsæt den nye her

'først ryk de resterende

For j As Integer = UBound(HighScoreCount) To i + 1 Step -1

'kopier array(j-1) til array(j)

HighScoreName(j) = HighScoreName(j - 1)

HighScoreCount(j) = HighScoreCount(j - 1)

Next j

HighScoreName(i) = TextBoxNavn.Text

HighScoreCount(i) = Val(TextBoxScore.Text)

Exit For

End If

Next i

'ryd textboxe

TextBoxNavn.Text = ""

TextBoxScore.Text = ""

'Skriv high score liste i fil så den kan læses næste gang

WriteHighScoreFile()

End Sub

'Vis high score liste

Private Sub ButtonShowList\_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles ButtonShowList.Click

Dim HighScoreText As String = ""

'sammen high score liste linje for linje

For i As Integer = 1 To UBound(HighScoreCount)

'tag alle pladser i array (vi bruger ikke plads 0)

If (HighScoreName(i) IsNot Nothing) AndAlso (HighScoreName(i).Trim <> "") Then

If (HighScoreText <> "") Then

'ny linje før hver spiller i listen, undtagen den første

HighScoreText = HighScoreText & vbNewLine

End If

'Linje f.x.: "Spiller1 : 230"

HighScoreText = HighScoreText & HighScoreName(i).PadRight(20) & ":" & HighScoreCount(i).ToString.PadLeft(5)

End If

Next i

'Vis liste i en meddelelses.box

MsgBox(HighScoreText, Title:="High score list")

End Sub

End Class

1. Rotation af Picturebox

Public Class Form1

Dim vinkel As Integer = 0

Dim PictureBox1Image As Image

Private Sub Form1\_Load(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles MyBase.Load

PictureBox1Image = Image.FromFile("C:\Users\Preben\Documents\blokdiagram biltælling.png")

End Sub

Private Sub Button1\_Click(ByVal sender As System.Object, ByVal e As System.EventArgs) Handles Button1.Click

PictureBox1.Invalidate()

vinkel = vinkel + 10

End Sub

Private Sub PictureBox1\_Paint(ByVal sender As Object, ByVal e As System.Windows.Forms.PaintEventArgs) Handles PictureBox1.Paint

With e.Graphics

.TranslateTransform(Me.PictureBox1.Width \ 2, Me.PictureBox1.Height \ 2)

.RotateTransform(vinkel)

.DrawImage(PictureBox1Image, -(Me.PictureBox1.Width \ 2), -(Me.PictureBox1.Height \ 2))

End With

End Sub

End Class